Flash vCams here

[chluaid]

For AS 2.0

Code: (reanimator.camera)

import flash.geom.Matrix;
import flash.geom.Transform;
import flash.geom.ColorTransform;
var cameraTrans:Transform = new Transform(this);
var stageTrans:Transform = new Transform(this._parent);
var w:Number = Stage.width;
var h:Number = Stage.height;
this._visible = false;
this.onEnterFrame = function () {
this._parent.filters = this.filters;
stageTrans.colorTransform = cameraTrans.colorTransform;
var stageMatrix:Matrix = cameraTrans.matrix;
stageMatrix.invert();
stageMatrix.translate(w*.5, h*.5);
stageTrans.matrix = stageMatrix;
};

For AS 3.0

Code: (Jaehl's AS3 cam, supports filters)

var cameraTrans:Transform = new Transform(this);
var stageTrans:Transform = new Transform(parent);
visible = false;

stage.addEventListener(Event.ENTER_FRAME, updateStage);
function updateStage(...rest) {
parent.filters = filters;
stageTrans.colorTransform = cameraTrans.colorTransform;
var stageMatrix:Matrix = cameraTrans.matrix;
stageMatrix.invert();
stageMatrix.translate(stage.stageWidth*.5, stage.stageHeight*.5);
stageTrans.matrix = stageMatrix;
};
updateStage();

addEventListener(Event.REMOVED_FROM_STAGE, resetStage);
function resetStage(...rest) {
stage.removeEventListener(Event.ENTER_FRAME, updateStage);
stageTrans.matrix = new Matrix();
stageTrans.colorTransform = new ColorTransform();
parent.filters = new Array();
}

To use these, simply create a movieclip symbol making sure that its Registration point is in the centre (as below):



Inside the symbol, create your vCam artwork (usually an empty square with the same dimensions as your movie) and put the above code on the same frame. Whenever you want to use the camera, simply drag it out of your Flash library onto the Stage. Tweening this camera symbol on the Stage creates camera moves, easy as that

vCam 1.0 was created by Sham Bhangal in 2004 for "Prowlies at the River"
reanimator.camera by Jarrad Hope was the first vCam to allow filters and rotation.
Jaehl's AS3 cam was created by request for us here, because he's so awesome.

As has always been the case, Actionscript programmers are encouraged to tweak and make their own enhancements/improvements to the vCam.
Animators and programmers, wherever you use the vCam or improve on it, always show respect by giving credit to the people who created it or contributed to the code.

[Vector]

DISCLAIMER: don't take my word for any of this, as I haven't had the time to learn AS3 in the last year an a half, and haven't had flash installed on my computer for about 9 months, but...

From a quick glance, it would appear that both the AS2 and AS3 cameras above do not clean up after themselves properly. It may not be a problem for the AS2 cam due to the way it keeps its-self operating, however the AS3 cam may leave your screen transformed even after you delete the camera from the stage.

What this means for you is if you want to stop using the camera by deleting it from the stage, you'll need to do a little workaround. After the last frame that you use your camera, add one more. On that frame, have the camera centred, and matching the stage's original width and height. After that frame you can delete the camera.

[chluaid]

yeah that's how I've been doing it but there's a way to do this in AS. Anthony Eden gave me the fix for Waterlollies but I seem to have misplaced the cam from that movie. It removes any stage transform when the cam clip is removed from the stage. I'm waiting for him to get back to me (which is why I PMd you about it) so when he does, I'll update the code above.

[adzy-2k6]

Couldnt you copy the cam from the waterlollies source file, or have you deleted it?. Odds are, that is the quickest way we will get it back

[chluaid]

Couldnt you copy the cam from the waterlollies source file, or have you deleted it?. Odds are, that is the quickest way we will get it back

I could but it's on my old computer which doesn't have a monitor, keyboard or mouse, since I'm using them all on my brand new machine. Probably easier to ask Jaehl or Snepo point out the problem and edit the post

[Jaehl]

Ta-da! 

Code:

import flash.geom.Matrix;
import flash.geom.Transform;
import flash.geom.ColorTransform;
var cameraTrans:Transform = new Transform(this);
var stageTrans:Transform = new Transform(this.parent);
var w:Number = stage.stageWidth;
var h:Number = stage.stageHeight;

stage.addEventListener(Event.ENTER_FRAME, updateStage);
function updateStage(...rest) {
//this._parent.filters = this.filters;
stageTrans.colorTransform = cameraTrans.colorTransform;
var stageMatrix:Matrix = cameraTrans.matrix;
stageMatrix.invert();
stageMatrix.translate(w*.5, h*.5);
stageTrans.matrix = stageMatrix;
};
updateStage();

this.addEventListener(Event.REMOVED_FROM_STAGE, resetStage);
function resetStage(...rest) {
stage.removeEventListener( Event.ENTER_FRAME, updateStage);
stageTrans.matrix = new Matrix();
}

[chluaid]

I hope you're earning a lot of money somewhere man

[Jaehl]

Oh God, don't even mention money, I'm so ridiculously poor right now!

[TheEYE]

That's AS3 correct Jaehl?
If you weren't already a MotM, you would be for this alone my friend, good on ya bud! 

[Jaehl]

No problem

And yeah, it's AS3. Here's the AS2 version:

Code:

import flash.geom.Matrix;
import flash.geom.Transform;
import flash.geom.ColorTransform;
var cameraTrans:Transform = new Transform(this);
var stageTrans:Transform = new Transform(this._parent);
var w:Number = Stage.width;
var h:Number = Stage.height;
this._visible = false;
this.onEnterFrame = function() {
this._parent.filters = this.filters;
stageTrans.colorTransform = cameraTrans.colorTransform;
var stageMatrix:Matrix = cameraTrans.matrix;
stageMatrix.invert();
stageMatrix.translate(w*.5, h*.5);
stageTrans.matrix = stageMatrix;
}

this.onUnload = function() {
stageTrans.matrix = new Matrix();
}

[Jeemanx]

I thought I'd ask here whether there are any tutorials on how to implement these cameras in flash (CS4)?

I've followed Adam's directions in this thread but can't get anything working. I've also downloaded the older example from the links page with Adam's 'waterfall' scene, but the code seems totally different to the examples shown here.

'pologies for the n00bness - but I'd never even thought of having a camera to move around in flash before today..

[EDIT] It's OK - I got it to work. I didn't have the correct publish settings in my scene.. D'oh!

[Darkswift2204]

Hey i need help i do what adams says but i cant get it to work. Do i have to make a square and make the square a symbol or what?

[Jaehl]

Make a rectangle that's exactly the same size as the movie itself, turn it into a movieclip, open it up, and stick the code on the first frame.

[Jaehl]

Update: The vCam now supports filters!

Code: (AS3)

var cameraTrans:Transform = new Transform(this);
var stageTrans:Transform = new Transform(parent);
visible = false;

stage.addEventListener(Event.ENTER_FRAME, updateStage);
function updateStage(...rest) {
parent.filters = filters;
stageTrans.colorTransform = cameraTrans.colorTransform;
var stageMatrix:Matrix = cameraTrans.matrix;
stageMatrix.invert();
stageMatrix.translate(stage.stageWidth*.5, stage.stageHeight*.5);
stageTrans.matrix = stageMatrix;
};
updateStage();

addEventListener(Event.REMOVED_FROM_STAGE, resetStage);
function resetStage(...rest) {
stage.removeEventListener(Event.ENTER_FRAME, updateStage);
stageTrans.matrix = new Matrix();
stageTrans.colorTransform = new ColorTransform();
parent.filters = new Array();
}